Here you go Ice. I said If not I'll program one lol, what kind if wheel do you use?

Just put this in excel

Option Explicit

Sub Main()

Dim Result As New Collection

Dim Data, This

Dim i As Long, j As Long

'Get the values from this region:

Data = Range("A3").CurrentRegion.Value

ReDim This(1 To UBound(Data, 2))

'Start the recursion to build the combinations into a collection

Process Result, Data, This, 1, WorksheetFunction.Min(Data) - 1

'Copy the combinations into a 2D array

ReDim Data(1 To Result.Count, 1 To UBound(Data, 2))

For Each This In Result

i = i + 1

For j = 1 To UBound(This)

Data(i, j) = This(j)

Next

Next

'Write into the sheet

Range("H3").Resize(UBound(Data), UBound(Data, 2)) = Data

End Sub

Private Sub Process(ByRef Result As Collection, ByRef Data, ByRef This, ByVal Index As Long, ByVal Min)

Dim i As Long

'For each row

For i = 1 To UBound(Data)

'Skip lower numbers

If Data(i, Index) > Min Then

'Get value into this slot

This(Index) = Data(i, Index)

'At the right end?

If Index < UBound(Data, 2) Then

'No, start another recursion one column to the right

Process Result, Data, This, Index + 1, This(Index)

Else

'Add this numbers as result

Result.Add This

End If

End If

Next

End Sub